title image


Smiley Re: Zwei Tabellen vergleichen und Zeilen anfügen
Hallo,



hab mal was gemacht, jedoch mit ein paar Sachen die noch zu

beachten sind.

1. ich arbeite mit einer "Hilfsspalte", in der ich mir merke welche Nummern ich

schon gefunden habe. Da mußt du halt eine Spalte Finden, die nicht benötigt wird.



2. Du öffnest die Textdatei ja mit Excel, also sind die Daten in einer 2. Datei.

Jetzt muß man nur noch wissen wie diese, und deine "Ziel"-Datei heißt.

Ich bin jetzt mal von Mappe1 und Mappe2 ausgegangen, und nehme weiter an,

dass beide Tabellenblätter an erster Stelle in der Datei sind.

(Wenn man sich die Mühe macht, die Textdatei öffnet, und die Daten dann in

die zu überprüfende Datei, auf ein Seperates Platt kopiert, könnte man das noch etwas optimieren.)



Auf Jeden Fall rate ich dir eine Sicherungskopie anzulegen.

und dann das ganze mal testen.







Option Explicit

Public Sub Vergleich()

Dim Quelle As Worksheet

Dim Ziel As Worksheet

Dim qlr As Long, zlr As Long

Dim Hilfspalte As Integer, Hilfstext As String

Dim i As Long

Dim c As Range



Hilfspalte = 20

Hilfstext = "abc"



Set Quelle = Workbooks("Mappe2").Sheets(1)

Set Ziel = Workbooks("Mappe1").Sheets(1)

qlr = Quelle.Cells(Rows.Count, 1).End(xlUp).Row

zlr = Ziel.Cells(Rows.Count, 1).End(xlUp).Row



For i = 1 To qlr  'Textdatei durchlaufen und fehlende Nummern übertragen, und gefundenen Markieren

    Set c = Ziel.Columns("A:A").Find(What:=Quelle.Cells(i, 1).Value, After:=Ziel.Cells(1, 1), LookIn:=xlFormulas, LookAt _

        :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _

        False)

    If c Is Nothing Then

        zlr = zlr + 1

        Ziel.Rows(zlr).Value = Quelle.Rows(i).Value

        Ziel.Cells(zlr, Hilfspalte).Value = Hilfstext

    Else

        Ziel.Cells(c.Row, Hilfspalte).Value = Hilfstext

    End If

Next i



For i = zlr To 1 Step -1 'Nicht gefunden Nummern löschen

    If Ziel.Cells(i, Hilfspalte).Value <> Hilfstext Then Ziel.Rows(i).Delete

Next i

Ziel.Columns(Hilfspalte).Clear

End Sub 





Code eingefügt mit Syntaxhighlighter 3.0




Gruss Klapperstorch
----------------------------------------------------
Aus Felern lernt man oder...
Edjucashon isnt woerking

geschrieben von

Login

E-Mail:
  

Passwort:
  

Beitrag anfügen

Symbol:
 
 
 
 
 
 
 
 
 
 
 
 
 

Überschrift: