title image


Smiley Re: Beziehung herstellen mit ADO
Hallo Phlipp,

zuerst einmal musst Du eine Verweis auf die ADOX setzen.



Danach kannst Du mal diesen Code versuchen den ich aus einem Access-Buch habe.

Was Du nicht benötigst musst Du eben wieder entfernen. Hoffe es hilft Dir weiter





Dim conn As ADODB.Connection

Dim cat As ADOX.Catalog

Dim tblLieferanten As ADOX.Table

Dim tblArtikel As ADOX.Table



Set cat = New ADOX.Catalog

Set tblLieferanten = New ADOX.Table

Set tblArtikel = New ADOX.Table



cat.Create "Provider=Microsoft.Jet.OLEDB.4.0; " & _

"Data Source=C:\Lieferanten.mdb"



' Verbindung zu neuer Datenbank

Set conn = cat.ActiveConnection



' Tabellen »Lieferanten« und »Artikel« anlegen

With tblLieferanten

' ParentCatalog setzen, um AutoIncrement setzen zu können

Set .ParentCatalog = cat

.Name = "Lieferanten"

' Datenfelder für »Lieferanten« anlegen

.Columns.Append "LiefNr", adInteger

.Columns("LiefNr").Properties("AutoIncrement") = True

.Columns.Append "Lieferant", adWChar, 255

' Primärschlüssel anlegen

.Keys.Append "PrimaryKey", adKeyPrimary, "LiefNr"

End With



cat.Tables.Append tblLieferanten

With tblArtikel

' ParentCatalog setzen, um AutoIncrement setzen zu können

Set .ParentCatalog = cat

.Name = "Artikel"

' Datenfelder für »Artikel«

.Columns.Append "ArtNr", adInteger

.Columns("ArtNr").Properties("AutoIncrement") = True

.Columns.Append "Artikel", adWChar, 50

.Columns.Append "LiefNr", adInteger

' Primärschlüssel anlegen

.Keys.Append "PrimaryKey", adKeyPrimary, "ArtNr"

' Fremdschlüssel ist Lieferanten.LiefNR

' damit wird referentielle Integrität aufgebaut

.Keys.Append "ArtLief", adKeyForeign, "LiefNr", _

"Lieferanten", "LiefNr"

End With



cat.Tables.Append tblArtikel

Set tblLieferanten = Nothing

Set tblArtikel = Nothing

Set cat = Nothing



Gruß

Markus

geschrieben von

Login

E-Mail:
  

Passwort:
  

Beitrag anfügen

Symbol:
 
 
 
 
 
 
 
 
 
 
 
 
 

Überschrift: