title image


Smiley Beispiel:
Jetzt erstellen wir mal ein VB-Projekt ohne VB, nur mit dem Editor (Notepad).

Dann sind die Steuerelemente genau so angeordnet, wie bei mir.

Mit dem Windoof-Explorer einen Ordner anlegen in den das Projekt soll.



Den Editor starten, folgenden Code reinkopieren und unter dem Namen Form1.frm

im eben erstellten Ordner speichern.



VERSION 5.00

Begin VB.Form Form1 

   BorderStyle     =   1  'Fixed Single

   Caption         =   "Form1"

   ClientHeight    =   1185

   ClientLeft      =   45

   ClientTop       =   330

   ClientWidth     =   1575

   LinkTopic       =   "Form1"

   MaxButton       =   0   'False

   MinButton       =   0   'False

   ScaleHeight     =   1185

   ScaleWidth      =   1575

   StartUpPosition =   3  'Windows Default

   Begin VB.CommandButton Command2 

      Caption         =   "Beenden"

      Height          =   255

      Left            =   120

      TabIndex        =   2

      Top             =   840

      Width           =   1335

   End

   Begin VB.CommandButton Command1 

      Caption         =   "Anzeigen"

      Height          =   255

      Left            =   120

      TabIndex        =   1

      Top             =   480

      Width           =   1335

   End

   Begin VB.TextBox Text1 

      Height          =   285

      Left            =   120

      TabIndex        =   0

      Text            =   "20"

      Top             =   120

      Width           =   1335

   End

End

Attribute VB_Name = "Form1"

Attribute VB_GlobalNameSpace = False

Attribute VB_Creatable = False

Attribute VB_PredeclaredId = True

Attribute VB_Exposed = False

Option Explicit



Private Sub Command1_Click()

Dim frmMain As New Form2

   

   frmMain.Init CLng(Me.Text1.Text)

   frmMain.Show vbModal

   Set frmMain = Nothing

End Sub



Private Sub Command2_Click()

   Unload Me

End Sub



Private Sub Text1_Validate(Cancel As Boolean)

   Cancel = Not IsNumeric(Me.Text1.Text)

End Sub

 





Im Editor Datei->Neu, folgenden Code reinkopieren und unter dem Namen Form2.frm

im eben erstellten Ordner speichern.



VERSION 5.00

Begin VB.Form Form2 

   BorderStyle     =   1  'Fixed Single

   Caption         =   "Form2"

   ClientHeight    =   2880

   ClientLeft      =   45

   ClientTop       =   330

   ClientWidth     =   5010

   LinkTopic       =   "Form2"

   MaxButton       =   0   'False

   MinButton       =   0   'False

   ScaleHeight     =   2880

   ScaleWidth      =   5010

   StartUpPosition =   3  'Windows Default

   Begin VB.Frame fraFix1 

      Height          =   495

      Left            =   120

      TabIndex        =   6

      Top             =   0

      Width           =   4815

   End

   Begin VB.VScrollBar VScroll1 

      Height          =   1815

      Left            =   4680

      TabIndex        =   5

      Top             =   480

      Width           =   255

   End

   Begin VB.Frame fraFix2 

      Height          =   735

      Left            =   120

      TabIndex        =   4

      Top             =   2160

      Width           =   4815

      Begin VB.CommandButton Command1 

         Caption         =   "Schließen"

         Height          =   255

         Left            =   3120

         TabIndex        =   0

         Top             =   360

         Width           =   1575

      End

   End

   Begin VB.Frame fraScroll 

      Height          =   1815

      Left            =   120

      TabIndex        =   1

      Top             =   360

      Width           =   4455

      Begin VB.TextBox Text1 

         Height          =   285

         Index           =   0

         Left            =   1680

         TabIndex        =   3

         Text            =   "Text1"

         Top             =   240

         Width           =   2655

      End

      Begin VB.Label Label1 

         Caption         =   "Label1"

         Height          =   255

         Index           =   0

         Left            =   120

         TabIndex        =   2

         Top             =   240

         Width           =   1335

      End

   End

End

Attribute VB_Name = "Form2"

Attribute VB_GlobalNameSpace = False

Attribute VB_Creatable = False

Attribute VB_PredeclaredId = True

Attribute VB_Exposed = False

Option Explicit



Private MlngAnzahl As Long



Public Sub Init(ByVal lngAnzahl As Long)

   '// wie viele Textboxen brauchen wir?

   MlngAnzahl = lngAnzahl

   CreateControls

End Sub





Private Sub Command1_Click()

   Unload Me

End Sub







Private Sub CreateControls()

'// Steuerelemente erstellen

Dim lngCount As Long

   

   '// bei 1 beginnen, die Steuerelemente mit dem

   '// Index 0 sind ja schon da

   For lngCount = 1 To MlngAnzahl - 1

      '// Label Laden

      Load Me.Label1.Item(lngCount)

      '// auf das Scrollframe setzen

      Set Me.Label1.Item(lngCount).Container = Me.fraScroll

      '// unter dem vorherigen platzieren

      Me.Label1.Item(lngCount).Top = Me.Label1.Item(lngCount - 1).Top + 400

      '// sichtbar machen

      Me.Label1.Item(lngCount).Visible = True

      '// Caption ändern

      Me.Label1.Item(lngCount).Caption = "Label" & lngCount + 1

      

      '// und mit der Textbox das gleiche

      Load Me.Text1.Item(lngCount)

      Set Me.Text1.Item(lngCount).Container = Me.fraScroll

      Me.Text1.Item(lngCount).Top = Me.Text1.Item(lngCount - 1).Top + 400

      Me.Text1.Item(lngCount).Visible = True

      Me.Text1.Item(lngCount).Text = "Text" & lngCount + 1

      

      '// Framegröße anpassen

      Me.fraScroll.Height = Me.Text1.Item(lngCount).Top + 600

   Next lngCount

   

   If MlngAnzahl > 4 Then

      '// Max-Wert = GesamtAnzahl - sichtbare

      Me.VScroll1.Max = MlngAnzahl - 4

      Me.VScroll1.SmallChange = 1

      If Me.VScroll1.Max >= 3 Then

         Me.VScroll1.LargeChange = Me.VScroll1.Max \ 3

      End If

   Else

      '// es wird keine Scrollbar benötigt

      Me.VScroll1.Visible = False

   End If

   

End Sub





Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)

'// Steuerelemente wieder entladen -> sauber aufräumen

Dim lngCount As Long



   For lngCount = MlngAnzahl - 1 To 1 Step -1

      Unload Me.Label1.Item(lngCount)

      Unload Me.Text1.Item(lngCount)

   Next lngCount

End Sub





Private Sub VScroll1_Change()

   '// Frame verschieben

   Me.fraScroll.Top = 360 - Me.VScroll1.Value * (Me.Text1(1).Top - Me.Text1(0).Top)

End Sub



Private Sub VScroll1_GotFocus()

   '// Scrollbar unsichtbar, sonst blinkts

   Me.VScroll1.Visible = False

End Sub



Private Sub VScroll1_LostFocus()

   '// Scrollbar wieder sichtbar

   Me.VScroll1.Visible = True

End Sub



 







Im Editor Datei->Neu, folgendes reinkopieren und unter dem Namen Project1.vbp

im eben erstellten Ordner speichern.



Type=Exe

Form=Form1.frm

Reference=*\G{00020430-0000-0000-C000-000000000046}#2.0#0#..\..\WINNT\System32\stdole2.tlb#OLE Automation

Form=Form2.frm

Startup="Form1"

Command32=""

Name="Project1"

HelpContextID="0"

CompatibleMode="0"

MajorVer=1

MinorVer=0

RevisionVer=0

AutoIncrementVer=0

ServerSupportFiles=0

VersionCompanyName="MicroMotion GmbH"

CompilationType=0

OptimizationType=0

FavorPentiumPro(tm)=0

CodeViewDebugInfo=0

NoAliasing=0

BoundsCheck=0

OverflowCheck=0

FlPointCheck=0

FDIVCheck=0

UnroundedFP=0

StartMode=0

Unattended=0

Retained=0

ThreadPerObject=0

MaxNumberOfThreads=1





Im Explorer nachkontrollieren, ob der Editor vielleicht ein .txt hinten angehängt hat.

Das macht er ab und zu, wenn ja, dann dieses .txt vom Dateinamen löschen.



Und jetzt kann's losgehen... Doppelclick auf die vbp

Im Startfenster kann man angeben, wieviele Textboxen im nächsten Fenster angezeigt werden

sollen.



Code eingefügt mit Syntaxhighlighter 1.16






Gruß
Gaga

___________________________________________________________________

Profilösungen für VB6
wenn nicht anders angegeben, sind alle Codebeispiele nicht getestet, nur getippt


geschrieben von

Login

E-Mail:
  

Passwort:
  

Beitrag anfügen

Symbol:
 
 
 
 
 
 
 
 
 
 
 
 
 

Überschrift: