title image


Smiley Re: Ich blick das nicht mit dem Serienbrief ich verzweifle fast..
Hallo,



nun gut, Du willst es so:





Public Sub kundenserienbrief(cSerienbrief_Tempdatei As String, DotPathFile As String, SBDocPathFile As String)

Dim rs As DAO.Recordset





'cSerienbrief_Tempdatei: Konstante beinhaltet Export-Dateinamen

If Dir(cSerienbrief_Tempdatei) = cSerienbrief_Tempdatei Then Kill cSerienbrief_Tempdatei



On Error GoTo SB_err

DoCmd.OutputTo acOutputQuery, "abfkundenserienbrief", acFormatRTF, cSerienbrief_Tempdatei

' Test, ob Kundenadressen selektiert wurden anhand der Dateigröße

Dim fs, f

Set fs = CreateObject("Scripting.FileSystemObject")

Set f = fs.Getfile(cSerienbrief_Tempdatei)

If f.Size < 1890 Then 'ca. Dateigröße bei ohne Kunde

MsgBox "Keine Kunden gefunden", vbExclamation + vbOKOnly, "Hinweis"

Kill cSerienbrief_Tempdatei

Exit Sub

End If



Dim wobj As New Word.Application 'Verweis auf Word-Library setzen

Dim Dok As Word.Document



Set Dok = wobj.Documents.Add(DotPathFile) ' DotPathFile enthalt Word-DOT-Vorlage-Datei des Serienbriefes



With wobj

.Visible = True

.Activate



With .ActiveDocument.MailMerge

.OpenDataSource cSerienbrief_Tempdatei 'Datenquelle definieren

.Destination = wdSendToNewDocument ' Serienbriefe als Dokument bestimmen

.Execute

End With



'.ActiveDocument.SaveAs FileName:=SBDocPathFile, FileFormat:=wdFormatDocument

'.Quit SaveChanges:=False

End With

exit_sub:

Set wobj = Nothing

Set Dok = Nothing

Exit Sub

SB_err:



If err.Number = 2501 Then Resume exit_sub 'Abruch der Parametereingabe/Abfrageausführung



MsgBox "Fehler: " & err.Number & " " & err.Description, vbExclamation + vbOKOnly, "Fehleingabe"

Resume exit_sub

End Sub


Gruß vom Bodensee
Franz, DF6GL

PS: Bitte nach Tipps oder Lösungsvorschlägen immer eine Erfolgs- / Mißerfolgsmeldung posten!


geschrieben von

Login

E-Mail:
  

Passwort:
  

Beitrag anfügen

Symbol:
 
 
 
 
 
 
 
 
 
 
 
 
 

Überschrift: