title image


Smiley Mit Klassenmodulen geht es (inside)
1. Erstelle ein Klassenmodul, das alle Deine Ereignisse, die Du auf die Textboxen anwenden willst enthält, hier clsTextBox. Hatte noch zum Testen ein paar Sachen mehr drin, die Du ja rausnehmen kannst





Option Compare Database

Option Explicit

Private WithEvents mtxt As Access.TextBox



Private mlngBackColor As Long

Private mlngBackColorEnter As Long

Public Sub Init(ByRef rtxt As Access.TextBox, Optional ByRef rBackColorEnter As Long = 8454143)

Set mtxt = rtxt

mlngBackColor = mtxt.BackColor

mlngBackColorEnter = rBackColorEnter

mtxt.OnEnter = "[Event Procedure]"

mtxt.OnExit = "[Event Procedure]"

mtxt.OnMouseDown = "[Event Procedure]"

End Sub



Private Sub Class_Terminate()

' tstDebugPrint "Class_Terminate clsTextBox"

End Sub



Private Sub mtxt_Enter()

mlngBackColor = mtxt.BackColor

mtxt.BackColor = mlngBackColorEnter

End Sub

Private Sub mtxt_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

MsgBox Button

MsgBox Shift

End Sub



Private Sub mtxt_Exit(Cancel As Integer)

mtxt.BackColor = mlngBackColor

End Sub

Public Sub Terminate()



Set mtxt = Nothing

' tstDebugPrint "Terminate clsTextBox"



End Sub





2. Im Form machst Du dann noch folgendes





Option Compare Database

Option Explicit

Private mCol As New Collection

'Die Collection sammtel die TextBox - Objecte

Private Sub Form_Load()

Dim c As Control

'Alle Controls durchlaufen und - wenn TextBox - an die Collection anhängen

For Each c In Me.Controls

If c.ControlType = acTextBox Then mCol.Add TxtInit(Me(c.Name), New clsTextBox)

Next c

End Sub



Private Function TxtInit(ByRef MyTextBox As Access.TextBox, ByRef robjTxt As Object) As Object

'Function zum Initalisieren von Textfeldern

robjTxt.Init MyTextBox

Set TxtInit = robjTxt

End Function






Mit freundlichen Grüßen aus Wuppertal

Walter Grimm EasyPointer

MS Access 2000/XP, MS SQL Server 2005, Windows XP
C#.Net 2.0 - VS 2005 Std
Bitte immer Erfolgs- oder Misserfolgsmeldung abgeben
++ Emails und Dateianhänge bitte nur nach Absprache ++

geschrieben von

Login

E-Mail:
  

Passwort:
  

Beitrag anfügen

Symbol:
 
 
 
 
 
 
 
 
 
 
 
 
 

Überschrift: